# 5.7 探究編譯器標志命令
**NOTE**:*此示例代碼可以在 https://github.com/dev-cafe/cmake-cookbook/tree/v1.0/chapter-5/recipe-07 中找到,其中包含一個C++例子。該示例在CMake 3.5版(或更高版本)中是有效的,并且已經在GNU/Linux、macOS和Windows上進行過測試。*
設置編譯器標志,對是否能正確編譯至關重要。不同的編譯器供應商,為類似的特性實現有不同的標志。即使是來自同一供應商的不同編譯器版本,在可用標志上也可能存在細微的差異。有時,會引入一些便于調試或優化目的的新標志。本示例中,我們將展示如何檢查所選編譯器是否可用某些標志。
## 準備工作
Sanitizers(請參考https://github.com/google/Sanitizers )已經成為靜態和動態代碼分析的非常有用的工具。通過使用適當的標志重新編譯代碼并鏈接到必要的庫,可以檢查內存錯誤(地址清理器)、未初始化的讀取(內存清理器)、線程安全(線程清理器)和未定義的行為(未定義的行為清理器)相關的問題。與同類型分析工具相比,Sanitizers帶來的性能損失通常要小得多,而且往往提供關于檢測到的問題的更詳細的信息。缺點是,代碼(可能還有工具鏈的一部分)需要使用附加的標志重新編譯。
本示例中,我們將設置一個項目,使用不同的Sanitizers來編譯代碼,并展示如何檢查,編譯器標志是否正確使用。
## 具體實施
Clang編譯器已經提供了Sanitizers,GCC也將其引入工具集中。它們是為C和C++程序而設計的。最新版本的Fortran也能使用這些編譯標志,并生成正確的儀表化庫和可執行程序。不過,本文將重點介紹C++示例。
1. 聲明一個C++11項目:
```cmake
cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
project(recipe-07 LANGUAGES CXX)
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
```
2. 聲明列表`CXX_BASIC_FLAGS`,其中包含構建項目時始終使用的編譯器標志`-g3`和`-O1`:
```cmake
list(APPEND CXX_BASIC_FLAGS "-g3" "-O1")
```
3. 這里需要包括CMake模塊` CheckCXXCompilerFlag.cmake `。C的模塊為` CheckCCompilerFlag.cmake `,Fotran的模塊為`CheckFortranCompilerFlag.cmake`(Fotran的模塊是在CMake 3.3添加):
```cmake
include(CheckCXXCompilerFlag)
```
4. 我們聲明一個`ASAN_FLAGS`變量,它包含Sanitizer所需的標志,并設置`CMAKE_REQUIRED_FLAGS`變量,`check_cxx_compiler_flag`函數在內部使用該變量:
```cmake
set(ASAN_FLAGS "-fsanitize=address -fno-omit-frame-pointer")
set(CMAKE_REQUIRED_FLAGS ${ASAN_FLAGS})
```
5. 我們調用`check_cxx_compiler_flag`來確保編譯器理解`ASAN_FLAGS`變量中的標志。調用函數后,我們取消設置`CMAKE_REQUIRED_FLAGS`:
```cmake
check_cxx_compiler_flag(${ASAN_FLAGS} asan_works)
unset(CMAKE_REQUIRED_FLAGS)
```
6. 如果編譯器理解這些選項,我們將變量轉換為一個列表,用分號替換空格:
```cmake
if(asan_works)
string(REPLACE " " ";" _asan_flags ${ASAN_FLAGS})
```
7. 我們添加了一個可執行的目標,為代碼定位Sanitizer:
```cmake
add_executable(asan-example asan-example.cpp)
```
8. 我們為可執行文件設置編譯器標志,以包含基本的和Sanitizer標志:
```cmake
target_compile_options(asan-example
PUBLIC
${CXX_BASIC_FLAGS}
${_asan_flags}
)
```
9. 最后,我們還將Sanitizer標志添加到鏈接器使用的標志集中。這將關閉`if(asan_works)`塊:
```cmake
target_link_libraries(asan-example PUBLIC ${_asan_flags})
endif()
```
完整的示例源代碼還展示了如何編譯和鏈接線程、內存和未定義的行為清理器的示例可執行程序。這里不詳細討論這些,因為我們使用相同的模式來檢查編譯器標志。
**NOTE**:*在GitHub上可以找到一個定制的CMake模塊,用于在您的系統上尋找對Sanitizer的支持:https://github.com/arsenm/sanitizers-cmake*
## 工作原理
`check_<lang>_compiler_flag`函數只是`check_<lang>_source_compiles`函數的包裝器。這些包裝器為特定代碼提供了一種快捷方式。在用例中,檢查特定代碼片段是否編譯并不重要,重要的是編譯器是否理解一組標志。
Sanitizer的編譯器標志也需要傳遞給鏈接器。可以使用`check_<lang>_compiler_flag`函數來實現,我們需要在調用之前設置`CMAKE_REQUIRED_FLAGS`變量。否則,作為第一個參數傳遞的標志將只對編譯器使用。
當前配置中需要注意的是,使用字符串變量和列表來設置編譯器標志。使用`target_compile_options`和`target_link_libraries`函數的字符串變量,將導致編譯器和/或鏈接器報錯。CMake將傳遞引用的這些選項,從而導致解析錯誤。這說明有必要用列表和隨后的字符串操作來表示這些選項,并用分號替換字符串變量中的空格。實際上,CMake中的列表是分號分隔的字符串。
## 更多信息
我們將在第7章,編寫一個函數來測試和設置編譯器標志,到時候再來回顧,并概括測試和設置編譯器標志的模式。
- Introduction
- 前言
- 第0章 配置環境
- 0.1 獲取代碼
- 0.2 Docker鏡像
- 0.3 安裝必要的軟件
- 0.4 測試環境
- 0.5 上報問題并提出改進建議
- 第1章 從可執行文件到庫
- 1.1 將單個源文件編譯為可執行文件
- 1.2 切換生成器
- 1.3 構建和鏈接靜態庫和動態庫
- 1.4 用條件句控制編譯
- 1.5 向用戶顯示選項
- 1.6 指定編譯器
- 1.7 切換構建類型
- 1.8 設置編譯器選項
- 1.9 為語言設定標準
- 1.10 使用控制流
- 第2章 檢測環境
- 2.1 檢測操作系統
- 2.2 處理與平臺相關的源代碼
- 2.3 處理與編譯器相關的源代碼
- 2.4 檢測處理器體系結構
- 2.5 檢測處理器指令集
- 2.6 為Eigen庫使能向量化
- 第3章 檢測外部庫和程序
- 3.1 檢測Python解釋器
- 3.2 檢測Python庫
- 3.3 檢測Python模塊和包
- 3.4 檢測BLAS和LAPACK數學庫
- 3.5 檢測OpenMP的并行環境
- 3.6 檢測MPI的并行環境
- 3.7 檢測Eigen庫
- 3.8 檢測Boost庫
- 3.9 檢測外部庫:Ⅰ. 使用pkg-config
- 3.10 檢測外部庫:Ⅱ. 自定義find模塊
- 第4章 創建和運行測試
- 4.1 創建一個簡單的單元測試
- 4.2 使用Catch2庫進行單元測試
- 4.3 使用Google Test庫進行單元測試
- 4.4 使用Boost Test進行單元測試
- 4.5 使用動態分析來檢測內存缺陷
- 4.6 預期測試失敗
- 4.7 使用超時測試運行時間過長的測試
- 4.8 并行測試
- 4.9 運行測試子集
- 4.10 使用測試固件
- 第5章 配置時和構建時的操作
- 5.1 使用平臺無關的文件操作
- 5.2 配置時運行自定義命令
- 5.3 構建時運行自定義命令:Ⅰ. 使用add_custom_command
- 5.4 構建時運行自定義命令:Ⅱ. 使用add_custom_target
- 5.5 構建時為特定目標運行自定義命令
- 5.6 探究編譯和鏈接命令
- 5.7 探究編譯器標志命令
- 5.8 探究可執行命令
- 5.9 使用生成器表達式微調配置和編譯
- 第6章 生成源碼
- 6.1 配置時生成源碼
- 6.2 使用Python在配置時生成源碼
- 6.3 構建時使用Python生成源碼
- 6.4 記錄項目版本信息以便報告
- 6.5 從文件中記錄項目版本
- 6.6 配置時記錄Git Hash值
- 6.7 構建時記錄Git Hash值
- 第7章 構建項目
- 7.1 使用函數和宏重用代碼
- 7.2 將CMake源代碼分成模塊
- 7.3 編寫函數來測試和設置編譯器標志
- 7.4 用指定參數定義函數或宏
- 7.5 重新定義函數和宏
- 7.6 使用廢棄函數、宏和變量
- 7.7 add_subdirectory的限定范圍
- 7.8 使用target_sources避免全局變量
- 7.9 組織Fortran項目
- 第8章 超級構建模式
- 8.1 使用超級構建模式
- 8.2 使用超級構建管理依賴項:Ⅰ.Boost庫
- 8.3 使用超級構建管理依賴項:Ⅱ.FFTW庫
- 8.4 使用超級構建管理依賴項:Ⅲ.Google Test框架
- 8.5 使用超級構建支持項目
- 第9章 語言混合項目
- 9.1 使用C/C++庫構建Fortran項目
- 9.2 使用Fortran庫構建C/C++項目
- 9.3 使用Cython構建C++和Python項目
- 9.4 使用Boost.Python構建C++和Python項目
- 9.5 使用pybind11構建C++和Python項目
- 9.6 使用Python CFFI混合C,C++,Fortran和Python
- 第10章 編寫安裝程序
- 10.1 安裝項目
- 10.2 生成輸出頭文件
- 10.3 輸出目標
- 10.4 安裝超級構建
- 第11章 打包項目
- 11.1 生成源代碼和二進制包
- 11.2 通過PyPI發布使用CMake/pybind11構建的C++/Python項目
- 11.3 通過PyPI發布使用CMake/CFFI構建C/Fortran/Python項目
- 11.4 以Conda包的形式發布一個簡單的項目
- 11.5 將Conda包作為依賴項發布給項目
- 第12章 構建文檔
- 12.1 使用Doxygen構建文檔
- 12.2 使用Sphinx構建文檔
- 12.3 結合Doxygen和Sphinx
- 第13章 選擇生成器和交叉編譯
- 13.1 使用CMake構建Visual Studio 2017項目
- 13.2 交叉編譯hello world示例
- 13.3 使用OpenMP并行化交叉編譯Windows二進制文件
- 第14章 測試面板
- 14.1 將測試部署到CDash
- 14.2 CDash顯示測試覆蓋率
- 14.3 使用AddressSanifier向CDash報告內存缺陷
- 14.4 使用ThreadSaniiser向CDash報告數據爭用
- 第15章 使用CMake構建已有項目
- 15.1 如何開始遷移項目
- 15.2 生成文件并編寫平臺檢查
- 15.3 檢測所需的鏈接和依賴關系
- 15.4 復制編譯標志
- 15.5 移植測試
- 15.6 移植安裝目標
- 15.7 進一步遷移的措施
- 15.8 項目轉換為CMake的常見問題
- 第16章 可能感興趣的書
- 16.1 留下評論——讓其他讀者知道你的想法